configure.ac 19 KB
Newer Older
1
AC_PREREQ(2.52)
2

3 4 5
dnl initialize autoconf
dnl we don't specify PACKAGE and VERSION because AS_VERSION puts it together
AC_INIT
6

Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
7
dnl when going to/from release please set the nano (fourth number) right !
8
dnl releases only do Wall, cvs and prerelease does Werror too
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
9
AS_VERSION(gst-plugins-base, GST_PLUGINS_BASE_VERSION, 0, 9, 4, 1,
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
10
    GST_CVS="no", GST_CVS="yes")
11

12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27
dnl can autoconf find the source ?
AC_CONFIG_SRCDIR([gst/sine/gstsinesrc.c])

dnl define the output header for config
AM_CONFIG_HEADER([config.h])

dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
AM_MAINTAINER_MODE

dnl sets host_* variables
AC_CANONICAL_HOST

dnl initialize automake
dnl FIXME: this is deprecated use, we should move PACKAGE and VERSION to
dnl AC_INIT, but then we need to parse the version to pass to AS_VERSION
AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
28 29

dnl our libraries and install dirs use major.minor as a version
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
30
GST_MAJORMINOR=$GST_PLUGINS_BASE_VERSION_MAJOR.$GST_PLUGINS_BASE_VERSION_MINOR
31
dnl we override it here if we need to for the release candidate of new series
32
# GST_MAJORMINOR=0.9
33 34 35 36 37 38 39
AC_SUBST(GST_MAJORMINOR)

dnl CURRENT, REVISION, AGE
dnl - library source changed -> increment REVISION
dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
dnl - interfaces added -> increment AGE
dnl - interfaces removed -> AGE = 0
40 41 42
dnl sets GST_LT_LDFLAGS
AS_LIBTOOL(GST, 2, 0, 0)
AS_LIBTOOL_TAGS
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
43
AM_PROG_LIBTOOL
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
44

45
dnl *** autotools stuff ****
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
46

47 48
dnl allow for different autotools
AS_AUTOTOOLS_ALTERNATE
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
49

50 51
dnl Add parameters for aclocal
AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
52

53 54 55
dnl set up gettext
dnl the version check needs to stay here because autopoint greps for it
AM_GNU_GETTEXT_VERSION([0.11.5])
56
AM_GNU_GETTEXT([external])
57
GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
58

59 60 61 62 63 64 65 66 67 68 69 70 71
dnl *** check for arguments to configure ***

GST_ARG_DEBUG
GST_ARG_PROFILING
GST_ARG_VALGRIND
GST_ARG_GCOV

GST_ARG_EXAMPLES

GST_ARG_WITH_PKG_CONFIG_PATH
GST_ARG_WITH_PACKAGE_NAME([GStreamer Base Plug-ins])
GST_ARG_WITH_PACKAGE_ORIGIN

Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120
dnl these are all the gst plug-ins, compilable without additional libs
GST_PLUGINS_ALL="\
	adder \
	audioconvert \
	audiorate \
	audioresample \
	audiotestsrc \
	ffmpegcolorspace \
	playback \
	sine \
	subparse \
	tcp \
	typefind \
	videotestsrc \
	videorate \
	videoscale \
	volume \
	"
AC_SUBST(GST_PLUGINS_ALL)

GST_PLUGINS_SELECTED=""

AC_ARG_WITH(plugins,
    AC_HELP_STRING([--with-plugins],[comma-separated list of plug-ins to compile]),
    [for i in `echo $withval | tr , ' '`; do
        if echo $GST_PLUGINS_ALL | grep $i > /dev/null
        then
            GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
        else
            echo "plug-in $i not recognized, ignoring..."
        fi
    done],
    [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])

AC_SUBST(GST_PLUGINS_SELECTED)


dnl ext plug-ins; plug-ins that have external dependencies
GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
  [HAVE_EXTERNAL=yes], enabled,
  [
    AC_MSG_NOTICE(building external plug-ins)
    BUILD_EXTERNAL="yes"
  ],[
    AC_MSG_NOTICE(all plug-ins with external dependencies will not be built)
    BUILD_EXTERNAL="no"
  ])
AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")

121 122 123 124 125 126 127 128 129 130 131 132
dnl *** checks for platform ***

dnl * hardware/architecture *

dnl common/m4/gst-arch.m4
dnl check CPU type
GST_ARCH

dnl *** checks for programs ***

dnl find a compiler
AC_PROG_CC
133

134
dnl determine c++ compiler
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
135
AC_PROG_CXX
136 137
dnl determine if c++ is available on this system
AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
138

139
dnl determine c++ preprocessor
140
dnl FIXME: do we need this ?
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
141
AC_PROG_CXXCPP
142 143 144 145 146 147 148 149 150 151 152 153

AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")

dnl check for documentation tools
GTK_DOC_CHECK([1.3])
AS_PATH_PYTHON([2.1])

dnl *** checks for libraries ***

dnl For interactive UNIX (a Sun thing)
dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
154 155
AC_ISC_POSIX

156 157 158 159 160 161 162 163 164
dnl *** checks for header files ***

dnl check if we have ANSI C header files
AC_HEADER_STDC

dnl used in gst/ffmpegcolorspace/mem.c
dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
AC_CHECK_HEADER([malloc.h])

165 166 167
dnl ffmpegcolorspace includes _stdint.h
AX_CREATE_STDINT_H

168 169 170 171 172 173 174 175 176 177 178
dnl *** checks for types/defines ***

dnl Check for FIONREAD ioctl declaration
dnl used in gst/tcp
GST_CHECK_FIONREAD

dnl *** checks for structures ***

dnl *** checks for compiler characteristics ***

dnl make sure we can use "inline" from C code
Benjamin Otte's avatar
Benjamin Otte committed
179
AC_C_INLINE
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
180

181 182 183 184 185 186
dnl *** checks for library functions ***

dnl Check for fast float to int casting as defined in C99
dnl used in gst-libs/gst/floatcast/floatcast.h
AC_C99_FUNC_LRINT
AC_C99_FUNC_LRINTF
187

188
dnl Check for a way to display the function name in debug output
189 190 191
GST_CHECK_FUNCTION

dnl *** checks for dependancy libraries ***
192

Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
193
dnl GLib is required
194 195
GST_GLIB_CHECK([2.6])

Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
196
dnl liboil is required
197 198 199
PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.2, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
if test "x${HAVE_LIBOIL}" != xyes ; then
  AC_ERROR([liboil-0.3 is required])
200 201
fi

Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238
dnl checks for gstreamer
dnl uninstalled is selected preferentially -- see pkg-config(1)
GST_REQ=0.9.3
GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)

dnl FIXME: get rid of this by making sure gstreamer-check brings it in
dnl check for "check", unit testing library/header
AM_PATH_CHECK(0.9.2, HAVE_CHECK=yes, HAVE_CHECK=no)
AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")


dnl GTK is optional and used in examples
HAVE_GTK=NO
PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
if test "x$HAVE_GTK_22" = "xyes"; then
  HAVE_GTK=yes
  GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
  AC_SUBST(GTK_VERSION)
  GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
  AC_SUBST(GTK_BASE_DIR)
else
  PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
fi
if test "x$HAVE_GTK_20" = "xyes"; then
  HAVE_GTK=yes
fi
GTK_CFLAGS=$GTK2_CFLAGS
GTK_LIBS=$GTK2_LIBS
AC_SUBST(GTK_LIBS)
AC_SUBST(GTK_CFLAGS)
AC_SUBST(HAVE_GTK)
AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")

239 240 241 242 243 244 245 246 247
dnl *** set variables based on configure arguments ***

dnl set license and copyright notice
GST_LICENSE="LGPL"
AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
AC_SUBST(GST_LICENSE)

dnl set location of plugin directory
GST_SET_PLUGINDIR
248

249 250 251 252 253 254 255 256 257 258 259
dnl define an ERROR_CFLAGS Makefile variable
GST_SET_ERROR_CFLAGS($GST_CVS)

dnl define correct level for debugging messages
GST_SET_LEVEL_DEFAULT($GST_CVS)

dnl decide on default elements
dnl FIXME: provide configure-time options for this
dnl FIXME: describe where exactly this gets used
dnl FIXME: decide if it's a problem that this could point to sinks from
dnl        depending plugin modules
260
DEFAULT_AUDIOSINK="alsasink"
261
DEFAULT_VIDEOSINK="xvimagesink"
262
DEFAULT_AUDIOSRC="alsasrc"
263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278
DEFAULT_VIDEOSRC="v4lsrc"
DEFAULT_VISUALIZER="goom"
case "$host" in 
  *-sun-* | *pc-solaris* )
    DEFAULT_AUDIOSINK="sunaudiosink"
    DEFAULT_VIDEOSINK="ximagesink"
    DEFAULT_AUDIOSRC="sunaudiosrc"
    ;;
  *-darwin* )
    DEFAULT_AUDIOSINK="osxaudiosink"
    DEFAULT_AUDIOSRC="osxaudiosrc"
    DEFAULT_VIDEOSINK="osxvideosink"
    ;;
esac

AC_SUBST(DEFAULT_AUDIOSINK)
279 280
AC_DEFINE_UNQUOTED(DEFAULT_AUDIOSINK, "$DEFAULT_AUDIOSINK",
  [Default audio sink])
281
AC_SUBST(DEFAULT_AUDIOSRC)
282 283
AC_DEFINE_UNQUOTED(DEFAULT_AUDIOSRC, "$DEFAULT_AUDIOSRC",
  [Default audio source])
284
AC_SUBST(DEFAULT_VIDEOSINK)
285 286
AC_DEFINE_UNQUOTED(DEFAULT_VIDEOSINK, "$DEFAULT_VIDEOSINK",
  [Default video sink])
287
AC_SUBST(DEFAULT_VIDEOSRC)
288 289
AC_DEFINE_UNQUOTED(DEFAULT_VIDEOSRC, "$DEFAULT_VIDEOSRC",
  [Default video source])
290
AC_SUBST(DEFAULT_VISUALIZER)
291 292
AC_DEFINE_UNQUOTED(DEFAULT_VISUALIZER, "$DEFAULT_VISUALIZER",
  [Default visualizer])
293

Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
294
dnl *** sys plug-ins ***
295

Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
296 297 298 299
echo
AC_MSG_NOTICE([Checking libraries for plugins in sys/])
echo

Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
300
dnl *** X11 ***
301 302 303 304
translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
GST_CHECK_FEATURE(X, [X libraries and plugins],
                  [ximagesink], [
  AC_PATH_XTRA
305 306 307 308 309
  ac_cflags_save="$CFLAGS"
  ac_cppflags_save="$CPPFLAGS"
  CFLAGS="$CFLAGS $X_CFLAGS"
  CPPFLAGS="$CPPFLAGS $X_CFLAGS"

310 311 312 313
  dnl now try to find the HEADER
  AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")

  if test "x$HAVE_X" = "xno"
314 315 316 317 318
  then
    AC_MSG_NOTICE([cannot find X11 development files])
  else
    dnl this is much more than we want
    X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
319 320
    dnl AC_PATH_XTRA only defines the path needed to find the X libs,
    dnl it does not add the libs; therefore we add them here
321 322 323 324 325
    X_LIBS="$X_LIBS -lX11"
    AC_SUBST(X_CFLAGS)
    AC_SUBST(X_LIBS)
  fi
  AC_SUBST(HAVE_X)
326 327
  CFLAGS="$ac_cflags_save"
  CPPFLAGS="$ac_cppflags_save"
328 329
])
  
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
330
dnl *** XVideo ***
331 332 333 334 335 336
dnl Look for the PIC library first, Debian requires it.
dnl Check debian-devel archives for gory details.
dnl 20020110:
dnl At the moment XFree86 doesn't distribute shared libXv due
dnl to unstable API.  On many platforms you CAN NOT link a shared
dnl lib to a static non-PIC lib.  This is what the xvideo GStreamer
337 338
dnl plug-in wants to do.  So Debian distributes a PIC compiled
dnl version of the static lib for plug-ins to link to when it is
339 340 341 342 343
dnl inappropriate to link the main application to libXv directly.
dnl FIXME: add check if this platform can support linking to a
dnl        non-PIC libXv, if not then don not use Xv.
dnl FIXME: perhaps warn user if they have a shared libXv since
dnl        this is an error until XFree86 starts shipping one
344 345
   
dnl Check for Xv extension
346
translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
347
GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
348
                  [xvimagesink], [
349
  if test x$HAVE_X = xyes; then
350 351
    AC_CHECK_LIB(Xv_pic, XvQueryExtension,
		 HAVE_XVIDEO="yes", HAVE_XVIDEO="no",
352
		 $X_LIBS -lXext)
353

354 355 356 357 358 359 360
    if test x$HAVE_XVIDEO = xyes; then
      XVIDEO_LIBS="-lXv_pic -lXext"
      AC_SUBST(XVIDEO_LIBS)
    else
      dnl try again using something else if we didn't find it first
      if test x$HAVE_XVIDEO = xno; then
        AC_CHECK_LIB(Xv, XvQueryExtension,
361
		   HAVE_XVIDEO="yes", HAVE_XVIDEO="no",
362
		   $X_LIBS -lXext)
363

364 365 366 367 368 369
        if test x$HAVE_XVIDEO = xyes; then
          XVIDEO_LIBS="-lXv -lXext"
          AC_SUBST(XVIDEO_LIBS)
        fi
      fi
    fi
370
  fi
371
])
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
372

373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395
dnl check for X Shm
translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], xshm, [
  if test x$HAVE_X = xyes; then
    AC_CHECK_LIB(Xext, XShmAttach, 
		 HAVE_XSHM="yes", HAVE_XSHM="no",
		 $X_LIBS) 
    if test "x$HAVE_XSHM" = "xyes"; then
      XSHM_LIBS="-lXext"
    else
      dnl On AIX, it is in XextSam instead, but we still need -lXext
      AC_CHECK_LIB(XextSam, XShmAttach, 
		   HAVE_XSHM="yes", HAVE_XSHM="no",
		   $X_LIBS) 
      if test "x$HAVE_XSHM" = "xyes"; then
	XSHM_LIBS="-lXext -lXextSam"
      fi
    fi
  fi
], , [ 
  AC_SUBST(HAVE_XSHM) 
  AC_SUBST(XSHM_LIBS) 
] )
396

397 398 399 400
dnl v4l/v4l2 checks have been moved down because they require X

dnl *** Video 4 Linux ***
dnl for information about the header/define, see sys/v4l/gstv4lelement.h
401 402 403
dnl renamed to GST_V4L in accordance with V4L2 below
translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], v4lsrc v4lmjpegsrc v4lmjpegsink, [
404
  # first check X
405
  HAVE_GST_V4L="no"
406
  if test "$HAVE_X" = "yes"
407
  then
408
    AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
409 410
#include <sys/types.h>
#define _LINUX_TIME_H
411
#define __user
412 413 414 415 416
#include <linux/videodev.h>
    ])
  fi
])

Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
417 418
dnl *** ext plug-ins ***
dnl keep this list sorted alphabetically !
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
419

420 421
if test "x$BUILD_EXTERNAL" = "xyes"; then

Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
422 423 424
echo
AC_MSG_NOTICE([Checking libraries for plugins in ext/])
echo
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
425 426 427

dnl *** alsa ***
translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
428
GST_CHECK_FEATURE(ALSA, [alsa plug-ins], gstalsa, [
429 430 431 432 433 434 435
  PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
    HAVE_ALSA="yes"
    AC_SUBST(ALSA_CFLAGS)
    AC_SUBST(ALSA_LIBS)
  ], [
    AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
  ])
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
436 437 438 439 440
])

dnl *** CDParanoia ***
translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
441 442 443 444
  GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface, 
                      cdda_open, -lm, 
                      cdda_interface.h, 
                      CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
445 446 447 448 449 450 451 452 453 454 455
                      HEADER_DIR="no"
                      FOUND_CDPARANOIA="yes")
  if test "x$FOUND_CDPARANOIA" != "xyes";
  then
    GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface, 
                        cdda_open, -lm, 
                        cdda/cdda_interface.h, 
                        CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
                        HEADER_DIR="yes"
                        FOUND_CDPARANOIA="yes")
  fi
456 457 458 459 460
  if test "x$HEADER_DIR" = "xyes";
  then
    AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
                       defined if cdda headers are in a cdda/ directory)
  fi
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
461
  AC_SUBST(CDPARANOIA_LIBS)
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
462 463 464 465 466 467 468 469
])
dnl FIXME : add second check somehow if that is necessary
dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)

dnl *** Gnome VFS ***
translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
GST_CHECK_FEATURE(GNOME_VFS, [Gnome VFS], gnomevfssrc, [
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
470 471 472
  PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, HAVE_GNOME_VFS="yes", HAVE_GNOME_VFS="no")
  AC_SUBST(GNOME_VFS_CFLAGS)
  AC_SUBST(GNOME_VFS_LIBS)
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
473 474
])

475 476 477
dnl *** libvisual ***
translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization plugins], libvisual, [
478
  PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0, HAVE_LIBVISUAL="yes", HAVE_LIBVISUAL="no")
479 480 481 482
  AC_SUBST(LIBVISUAL_CFLAGS)
  AC_SUBST(LIBVISUAL_LIBS)
])

483 484 485
dnl *** ogg ***
translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
GST_CHECK_FEATURE(OGG, [ogg de/encoder], oggdemux oggmux, [
486 487 488 489 490 491 492 493
  PKG_CHECK_MODULES(OGG, ogg >= 1.0, [
    HAVE_OGG="yes"
    AC_SUBST(OGG_CFLAGS)
    AC_SUBST(OGG_LIBS)
  ], [
    XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
    AS_SCRUB_INCLUDE(OGG_CFLAGS)
  ])
494 495
])

Benjamin Otte's avatar
Benjamin Otte committed
496 497
dnl *** theora ***
translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
Thomas Vander Stichele's avatar
add enc  
Thomas Vander Stichele committed
498
GST_CHECK_FEATURE(THEORA, [ogg theora codec], theoradec theoraenc, [
499 500 501 502 503
  PKG_CHECK_MODULES(THEORA, theora, [
    HAVE_THEORA="yes"
    AC_SUBST(THEORA_LIBS)
    AC_SUBST(THEORA_CFLAGS)
  ], [
504
    GST_CHECK_LIBHEADER(THEORA, theora, theora_version_string, "-logg", theora/theora.h, THEORA_LIBS="-ltheora -logg")
505 506
    AC_SUBST(THEORA_LIBS)
  ])
Benjamin Otte's avatar
Benjamin Otte committed
507 508
])

Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
509 510 511
dnl *** vorbis ***
dnl AM_PATH_VORBIS only takes two options
translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
512
GST_CHECK_FEATURE(VORBIS, [vorbis plug-in], vorbisenc vorbisdec, [
513 514 515 516 517 518
  PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0, [
    HAVE_VORBIS="yes"
  ], [
    XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
    AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
  ])
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
519
])
520 521
if test "x$HAVE_VORBIS" = "xyes"; then
  ac_cflags_save="$CFLAGS"
522
  dnl FIXME: does this work on non-gcc? -- Company
523
  dnl FIXME: no, it doesn't.  Why is this here in the first place ? -- thomasvs
524 525 526 527 528 529 530 531 532 533 534 535 536 537 538
  CFLAGS="-Wall -Werror"
  AC_COMPILE_IFELSE(
    AC_LANG_PROGRAM([
#include <vorbis/codec.h>
                     ],[
vorbis_dsp_state *v;

vorbis_synthesis_restart (v);
                     ]), HAVE_VSR=yes, HAVE_VSR=no)
  if test "x$HAVE_VSR" = "xyes"; then
    AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
                       [defined if vorbis_synthesis_restart is present])
  fi
  CFLAGS="$ac_cflags_save"
fi
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
539

540 541
fi dnl of EXT plugins

Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
542 543 544 545
dnl ######################################################################
dnl # Check command line parameters, and set shell variables accordingly #
dnl ######################################################################

546
dnl seeking needs freetype, so check for it here
547 548 549
PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
  AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
])
550 551 552 553 554
dnl make the HAVE_FT2 variable available to automake and Makefile.am
AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
AC_SUBST(FT2_CFLAGS)
AC_SUBST(FT2_LIBS)

555 556 557 558 559 560 561 562 563 564 565 566 567 568 569 570 571 572 573 574 575 576 577 578 579
dnl *** finalize CFLAGS, LDFLAGS, LIBS

dnl Overview:
dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
dnl GST_*:              flags shared by all built objects
dnl GST_LT_LDFLAGS:     library versioning of our libraries
dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins

dnl GST_OPTION_CFLAGS
if test "x$USE_DEBUG" = xyes; then
   PROFILE_CFLAGS="-g"
fi
AC_SUBST(PROFILE_CFLAGS)

DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
AC_SUBST(DEPRECATED_CFLAGS)

dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
AC_SUBST(GST_OPTION_CFLAGS)

dnl our libraries need to be versioned correctly
AC_SUBST(GST_LT_LDFLAGS)

dnl FIXME: do we want to rename to GST_ALL_* ?
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
580
dnl prefer internal headers to already installed ones
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
581
dnl also add builddir include for enumtypes and marshal
582
dnl add ERROR_CFLAGS, but overridable
583
GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
584
AC_SUBST(GST_CFLAGS)
585
AC_SUBST(GST_LIBS)
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
586

587 588 589 590
dnl this really should only contain flags, not libs - they get added before
dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' -no-undefined"
AC_SUBST(GST_PLUGIN_LDFLAGS)
591

592
dnl *** output files ***
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
593

Andy Wingo Wingo's avatar
Andy Wingo Wingo committed
594
AC_CONFIG_FILES(
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
595
Makefile
596
gst-plugins-base.spec
597
gst/Makefile
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
598
gst/adder/Makefile
599
gst/audioconvert/Makefile
600
gst/audiorate/Makefile
601
gst/audioresample/Makefile
Stefan Kost's avatar
Stefan Kost committed
602
gst/audiotestsrc/Makefile
603
gst/ffmpegcolorspace/Makefile
604
gst/playback/Makefile
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
605
gst/sine/Makefile
606
gst/subparse/Makefile
Wim Taymans's avatar
Wim Taymans committed
607
gst/tcp/Makefile
608
gst/typefind/Makefile
David Schleef's avatar
David Schleef committed
609
gst/videotestsrc/Makefile
610
gst/videorate/Makefile
611
gst/videoscale/Makefile
612
gst/volume/Makefile
613
sys/Makefile
614
sys/ximage/Makefile
615
sys/xvimage/Makefile
Andy Wingo Wingo's avatar
Andy Wingo Wingo committed
616
sys/v4l/Makefile
617
ext/Makefile
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
618
ext/alsa/Makefile
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
619
ext/cdparanoia/Makefile
620
ext/gnomevfs/Makefile
621
ext/libvisual/Makefile
622
ext/ogg/Makefile
Benjamin Otte's avatar
Benjamin Otte committed
623 624
ext/theora/Makefile
ext/vorbis/Makefile
625
gst-libs/Makefile
626 627
gst-libs/gst/Makefile
gst-libs/gst/audio/Makefile
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
628
gst-libs/gst/floatcast/Makefile
629
gst-libs/gst/interfaces/Makefile
Andy Wingo Wingo's avatar
Andy Wingo Wingo committed
630
gst-libs/gst/net/Makefile
631
gst-libs/gst/riff/Makefile
632
gst-libs/gst/rtp/Makefile
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
633
gst-libs/gst/tag/Makefile
634
gst-libs/gst/video/Makefile
635
gst-libs/ext/Makefile
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
636
examples/seeking/Makefile
Andy Wingo Wingo's avatar
Andy Wingo Wingo committed
637
examples/Makefile
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
638
tools/Makefile
639
pkgconfig/Makefile
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
640 641
pkgconfig/gstreamer-plugins-base.pc
pkgconfig/gstreamer-plugins-base-uninstalled.pc
642
check/Makefile
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
643 644
docs/Makefile
docs/libs/Makefile
645
docs/plugins/Makefile
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
646
docs/version.entities
647
po/Makefile.in
648 649 650
common/Makefile
common/m4/Makefile
m4/Makefile
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
651
)
Andy Wingo Wingo's avatar
Andy Wingo Wingo committed
652 653
AC_OUTPUT

654 655
echo "configure: *** Core plug-ins, always built:"
( for i in $GST_PLUGINS_ALL; do echo -e '\t'$i; done ) | sort
656 657
echo
echo -n "configure: *** Plug-ins relying on libraries that will be built:"
658
echo -e "$GST_PLUGINS_YES" | sort
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
659
echo
660
echo -n "configure: *** Plug-ins relying on libraries that will NOT be built:"
661
echo -e "$GST_PLUGINS_NO" | sort
Thomas Vander Stichele's avatar
Thomas Vander Stichele committed
662
echo
663 664 665
if test "x$BUILD_EXTERNAL" = "xno"; then
  echo "configure: *** No external plug-ins will be built"
fi