configure.ac 61.3 KB
Newer Older
1
dnl -*- mode: m4 -*-
2
AC_PREREQ([2.63])
3

4
m4_define([dbus_major_version], [1])
5
m4_define([dbus_minor_version], [7])
6
m4_define([dbus_micro_version], [5])
7 8
m4_define([dbus_version],
          [dbus_major_version.dbus_minor_version.dbus_micro_version])
9
AC_INIT([dbus],[dbus_version],[https://bugs.freedesktop.org/enter_bug.cgi?product=dbus],[dbus])
10

11
AC_CANONICAL_HOST
12

13
AC_CONFIG_HEADERS([config.h])
14 15
AC_CONFIG_MACRO_DIR([m4])

16
AM_INIT_AUTOMAKE([1.10 tar-ustar -Wno-portability])
17

18 19
GETTEXT_PACKAGE=dbus-1
AC_SUBST(GETTEXT_PACKAGE)
20
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
21

22 23 24
# By default, rebuild autotools files on demand; only use ./missing if the
# user says --disable-maintainer-mode (some distributions like to do this)
AM_MAINTAINER_MODE([enable])
25

26 27
m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])

28 29
AC_DEFINE_UNQUOTED(DBUS_DAEMON_NAME,"dbus-daemon",[Name of executable])

30
# libtool versioning - this applies to libdbus
John Palmieri's avatar
John Palmieri committed
31 32 33
#
# See http://sources.redhat.com/autobook/autobook/autobook_91.html#SEC91 for details
#
34 35

## increment if the interface has additions, changes, removals.
36
LT_CURRENT=11
37 38 39

## increment any time the source changes; set to
##  0 if you increment CURRENT
Simon McVittie's avatar
Simon McVittie committed
40
LT_REVISION=2
41 42 43 44

## increment if any interfaces have been added; set to 0
## if any interfaces have been changed or removed. removal has
## precedence over adding, so set to 0 if both happened.
45
LT_AGE=8
46

John Palmieri's avatar
John Palmieri committed
47 48 49 50
AC_SUBST(LT_CURRENT)
AC_SUBST(LT_REVISION)
AC_SUBST(LT_AGE)

51 52 53 54 55 56 57 58 59
DBUS_MAJOR_VERSION=dbus_major_version
DBUS_MINOR_VERSION=dbus_minor_version
DBUS_MICRO_VERSION=dbus_micro_version
DBUS_VERSION=dbus_major_version.dbus_minor_version.dbus_micro_version

AC_SUBST(DBUS_MAJOR_VERSION)
AC_SUBST(DBUS_MINOR_VERSION)
AC_SUBST(DBUS_MICRO_VERSION)
AC_SUBST(DBUS_VERSION)
John Palmieri's avatar
John Palmieri committed
60

61
AC_PROG_CC
62
AM_PROG_CC_C_O
63
AC_PROG_CXX
64
AC_USE_SYSTEM_EXTENSIONS
65 66
AC_ISC_POSIX
AC_HEADER_STDC
67
AC_C_INLINE
68
AM_PROG_LIBTOOL
69
AC_PROG_MKDIR_P
70 71
COMPILER_COVERAGE
COMPILER_OPTIMISATIONS
72
PKG_PROG_PKG_CONFIG
73

74 75 76 77
# Initialize libtool
LT_INIT([win32-dll])
LT_LANG([Windows Resource])

78 79
# Set some internal variables depending on the platform for later use.
dbus_win=no
80
dbus_cygwin=no
81 82
dbus_unix=no
case "${host}" in
83 84 85 86
    *-mingw32ce*)
        dbus_win=yes
        dbus_wince=yes
        ;;
87 88 89
    *-mingw32*)
        dbus_win=yes
        ;;
90 91 92 93
    *-cygwin*)
        dbus_cygwin=yes
        dbus_unix=yes
        ;;
94 95 96 97 98 99 100 101 102 103
    *)
        dbus_unix=yes
       ;;
esac

# Special defines for certain platforms
if test "$dbus_win" = yes; then
    AC_DEFINE(DBUS_WIN,1,[Defined if we run on a W32 API based system])
    BUILD_TIMESTAMP=`date --iso-8601=minutes`
    AC_SUBST(BUILD_TIMESTAMP)
104 105 106
    # Assume DBUS_VERSION is always three numbers
    BUILD_FILEVERSION=`echo "$DBUS_VERSION" | sed -e 's/\./,/g'`,0
    AC_SUBST(BUILD_FILEVERSION)
107 108 109 110
    AC_CHECK_TOOL(WINDRES, windres, no)
    if test "$WINDRES" = no; then
      AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
    fi
111 112
    if test "$dbus_wince" = yes; then
      AC_DEFINE(DBUS_WINCE,1,[Defined if we run on a W32 CE API based system])
113
      AC_DEFINE(_WIN32_WCE, 0x0502, [Defined to get newer W32 CE APIs])
114
    fi
115 116 117
else
    AC_DEFINE(DBUS_UNIX,1,[Defined if we run on a Unix-based system])
fi
118 119 120
if test "$dbus_cygwin" = yes; then
    AC_DEFINE(DBUS_CYGWIN,1,[Defined if we run on a cygwin API based system])
fi
121

122
AM_CONDITIONAL(DBUS_WIN, test "$dbus_win" = yes)
123
AM_CONDITIONAL(DBUS_WINCE, test "$dbus_wince" = yes)
124
AM_CONDITIONAL(DBUS_UNIX, test "$dbus_unix" = yes)
125
AM_CONDITIONAL(DBUS_CYGWIN, test "$dbus_cygwin" = yes)
126

127 128 129
# this must come first: other options use this to set their defaults
AC_ARG_ENABLE([developer],
  [AS_HELP_STRING([--enable-developer],
130 131 132
    [set defaults to be appropriate for a D-Bus developer instead of a distribution/end-user])],
  [],
  [enable_developer=no])
133

134 135 136 137 138 139 140 141 142 143
DBUS_STATIC_BUILD_CPPFLAGS=
if test "x$enable_shared" = xno; then
    # On Windows, linking against the static library requires special effort
    # to turn off DLL import/export processing. We normally link some things
    # against the dynamic library, but if we're not building that, we'll
    # have to link everything statically.
    DBUS_STATIC_BUILD_CPPFLAGS=-DDBUS_STATIC_BUILD
fi
AC_SUBST([DBUS_STATIC_BUILD_CPPFLAGS])

144
AC_ARG_ENABLE(ansi, AS_HELP_STRING([--enable-ansi],[enable -ansi -pedantic gcc flags]),enable_ansi=$enableval,enable_ansi=no)
145 146
AC_ARG_ENABLE(verbose-mode, AS_HELP_STRING([--enable-verbose-mode],[support verbose debug mode]),enable_verbose_mode=$enableval,enable_verbose_mode=$enable_developer)
AC_ARG_ENABLE(asserts, AS_HELP_STRING([--enable-asserts],[include assertion checks]),enable_asserts=$enableval,enable_asserts=$enable_developer)
147 148 149 150 151
AC_ARG_ENABLE(checks, AS_HELP_STRING([--enable-checks],[include sanity checks on public API]),enable_checks=$enableval,enable_checks=yes)
AC_ARG_ENABLE(xml-docs, AS_HELP_STRING([--enable-xml-docs],[build XML documentation (requires xmlto)]),enable_xml_docs=$enableval,enable_xml_docs=auto)
AC_ARG_ENABLE(doxygen-docs, AS_HELP_STRING([--enable-doxygen-docs],[build DOXYGEN documentation (requires Doxygen)]),enable_doxygen_docs=$enableval,enable_doxygen_docs=auto)
AC_ARG_ENABLE(abstract-sockets, AS_HELP_STRING([--enable-abstract-sockets],[use abstract socket namespace (linux only)]),enable_abstract_sockets=$enableval,enable_abstract_sockets=auto)
AC_ARG_ENABLE(selinux, AS_HELP_STRING([--enable-selinux],[build with SELinux support]),enable_selinux=$enableval,enable_selinux=auto)
152
AC_ARG_ENABLE(libaudit,AS_HELP_STRING([--enable-libaudit],[build audit daemon support for SELinux]),enable_libaudit=$enableval,enable_libaudit=auto)
153
AC_ARG_ENABLE(inotify, AS_HELP_STRING([--enable-inotify],[build with inotify support (linux only)]),enable_inotify=$enableval,enable_inotify=auto)
154
AC_ARG_ENABLE(kqueue, AS_HELP_STRING([--enable-kqueue],[build with kqueue support]),enable_kqueue=$enableval,enable_kqueue=auto)
John Palmieri's avatar
John Palmieri committed
155
AC_ARG_ENABLE(console-owner-file, AS_HELP_STRING([--enable-console-owner-file],[enable console owner file]),enable_console_owner_file=$enableval,enable_console_owner_file=auto)
Benjamin Reed's avatar
Benjamin Reed committed
156
AC_ARG_ENABLE(launchd, AS_HELP_STRING([--enable-launchd],[build with launchd auto-launch support]),enable_launchd=$enableval,enable_launchd=auto)
157
AC_ARG_ENABLE(systemd, AS_HELP_STRING([--enable-systemd],[build with systemd at_console support]),enable_systemd=$enableval,enable_systemd=auto)
158 159 160 161 162 163 164

AC_ARG_WITH(init-scripts, AS_HELP_STRING([--with-init-scripts=[redhat]],[Style of init scripts to install]))
AC_ARG_WITH(session-socket-dir, AS_HELP_STRING([--with-session-socket-dir=[dirname]],[Where to put sockets for the per-login-session message bus]))
AC_ARG_WITH(test-socket-dir, AS_HELP_STRING([--with-test-socket-dir=[dirname]],[Where to put sockets for make check]))
AC_ARG_WITH(system-pid-file, AS_HELP_STRING([--with-system-pid-file=[pidfile]],[PID file for systemwide daemon]))
AC_ARG_WITH(system-socket, AS_HELP_STRING([--with-system-socket=[filename]],[UNIX domain socket for systemwide daemon]))
AC_ARG_WITH(console-auth-dir, AS_HELP_STRING([--with-console-auth-dir=[dirname]],[directory to check for console ownerhip]))
John Palmieri's avatar
John Palmieri committed
165
AC_ARG_WITH(console-owner-file, AS_HELP_STRING([--with-console-owner-file=[filename]],[file whose owner determines current console owner]))
Benjamin Reed's avatar
Benjamin Reed committed
166
AC_ARG_WITH(launchd-agent-dir, AS_HELP_STRING([--with-launchd-agent-dir=[dirname]],[directory to put the launchd agent (default: /Library/LaunchAgents)]))
167
AC_ARG_WITH(dbus_user, AS_HELP_STRING([--with-dbus-user=<user>],[User for running the DBUS daemon (messagebus)]))
John Palmieri's avatar
John Palmieri committed
168
AC_ARG_WITH(dbus_daemondir, AS_HELP_STRING([--with-dbus-daemondir=[dirname]],[Directory for installing the DBUS daemon]))
169

170 171 172
AC_ARG_ENABLE([embedded-tests],
  AS_HELP_STRING([--enable-embedded-tests],
    [enable unit test code in the library and binaries]),
173
  [], [enable_embedded_tests=$enable_developer])
174 175 176 177 178 179 180 181 182
AC_ARG_ENABLE([modular-tests],
  AS_HELP_STRING([--enable-modular-tests],
    [enable modular regression tests (requires GLib)]),
  [], [enable_modular_tests=auto])
# --enable-tests overrides both --enable-embedded-tests and
# --enable-modular-tests
AC_ARG_ENABLE([tests],
  AS_HELP_STRING([--enable-tests],
    [enable/disable all tests, overriding embedded-tests/modular-tests]),
183 184 185 186 187 188 189 190
  [
  if test "x$enableval" = xyes; then
    AC_MSG_NOTICE([Full test coverage was requested with --enable-tests=yes])
    AC_MSG_NOTICE([This has many dependencies (GLib, dbus-glib, Python)])
  fi
  enable_embedded_tests=$enableval
  enable_modular_tests=$enableval
  ],
191 192 193
  [])

# DBUS_ENABLE_EMBEDDED_TESTS controls unit tests built in to .c files
194
# and also some stuff in the test/ subdir.
195 196 197 198 199 200 201 202 203 204 205
AM_CONDITIONAL([DBUS_ENABLE_EMBEDDED_TESTS],
  [test "x$enable_embedded_tests" = xyes])
if test "x$enable_embedded_tests" = xyes; then
    AC_DEFINE([DBUS_ENABLE_EMBEDDED_TESTS], [1],
      [Define to build test code into the library and binaries])
fi

# DBUS_ENABLE_MODULAR_TESTS controls tests that work based on public API.
# These use GTest, from GLib, because life's too short. They're enabled by
# default (unless you don't have GLib), because they don't bloat the library
# or binaries.
206

207
AC_DEFINE([GLIB_VERSION_MIN_REQUIRED], [GLIB_VERSION_2_26], [Ignore post-2.26 deprecations])
208
AC_DEFINE([GLIB_VERSION_MAX_ALLOWED], [GLIB_VERSION_2_32], [Prevent post-2.32 APIs])
209

210 211
with_glib=yes

212 213
AS_IF([test "x$enable_modular_tests" != xno],
  [
214
  PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.24, gio-2.0 >= 2.24],
215 216
    [],
    [if test "x$enable_modular_tests" = xyes; then
217 218
      AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires GLib])
      AC_MSG_ERROR([$GLIB_ERRORS])
219
    else # assumed to be "auto"
220
      with_glib=no
221
    fi])
222 223 224 225 226 227 228 229 230 231 232
  ],
  [with_glib=no])

# Not required, because we can use internal APIs (but that makes the
# "installable tests" less useful as integration tests)
AC_ARG_WITH([dbus_glib],
  [AS_HELP_STRING([--with-dbus-glib], [Use dbus-glib for regression tests])],
  [],
  [with_dbus_glib=auto])
AS_IF([test "x$with_dbus_glib" != xno],
  [PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1],
233
    [],
234 235 236 237 238 239 240
    [AS_IF([test "x$with_dbus_glib" = xyes],
      dnl specifically requested, but not found
      [AC_MSG_ERROR([$DBUS_GLIB_ERRORS])],
      dnl else: assumed to be "auto"
      [with_dbus_glib=no])])])
AM_CONDITIONAL([DBUS_WITH_DBUS_GLIB], [test "x$with_dbus_glib" != xno])

241
if test "x$enable_modular_tests" != xno; then
242
  AC_DEFINE([DBUS_ENABLE_MODULAR_TESTS], [1],
243
    [Define to build independent test binaries])
244
fi
245
AM_CONDITIONAL([DBUS_ENABLE_MODULAR_TESTS],
246 247 248 249 250 251 252
  [test "x$enable_modular_tests" != xno])

if test "x$with_glib" != xno; then
  AC_DEFINE([DBUS_WITH_GLIB], [1],
    [Define if GLib, GObject, GIO are available])
fi
AM_CONDITIONAL([DBUS_WITH_GLIB], [test "x$with_glib" != xno])
253

254 255 256 257 258 259
AC_ARG_ENABLE([installed-tests],
  AS_HELP_STRING([--enable-installed-tests],
    [enable unit test code in the library and binaries]),
  [], [enable_installed_tests=no])
AM_CONDITIONAL([DBUS_ENABLE_INSTALLED_TESTS],
  [test "x$enable_installed_tests" = xyes])
260

261 262
if test "x$enable_tests" = xyes; then
  # full test coverage is required, Python is a hard dependency
263
  AC_MSG_NOTICE([Full test coverage (--enable-tests=yes) requires Python, dbus-python, pygobject])
264
  AM_PATH_PYTHON([2.6])
265 266 267 268 269 270 271
  AC_MSG_CHECKING([for Python modules for full test coverage])
  if "$PYTHON" -c "import dbus, gobject, dbus.mainloop.glib"; then
    AC_MSG_RESULT([yes])
  else
    AC_MSG_RESULT([no])
    AC_MSG_ERROR([cannot import dbus, gobject, dbus.mainloop.glib Python modules])
  fi
272 273 274 275 276
else
  # --enable-tests not given: do not abort if Python is missing
  AM_PATH_PYTHON([2.6], [], [:])
fi

277 278 279
if test x$enable_verbose_mode = xyes; then
    AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
fi
280

281 282
if test x$enable_asserts = xno; then
    AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
283
    DISABLE_UNUSED_WARNINGS="unused-label"
284
    R_DYNAMIC_LDFLAG=""
285 286 287 288 289
    if test x$enable_embedded_tests = xyes; then
        DISABLE_UNUSED_WARNINGS="$DISABLE_UNUSED_WARNINGS \
                unused-but-set-variable unused-variable \
                unused-function"
    fi
290 291
else
    # -rdynamic is needed for glibc's backtrace_symbols to work.
292
    # No clue how much overhead this adds, but it's useful
293 294 295 296 297 298 299
    # to do this on any assertion failure,
    # so for now it's enabled anytime asserts are (currently not
    # in production builds).

    # To get -rdynamic you pass -export-dynamic to libtool.
    AC_DEFINE(DBUS_BUILT_R_DYNAMIC,1,[whether -export-dynamic was passed to libtool])
    R_DYNAMIC_LDFLAG=-export-dynamic
300
fi
301 302
AC_SUBST(R_DYNAMIC_LDFLAG)

303 304
if test x$enable_checks = xno; then
    AC_DEFINE(DBUS_DISABLE_CHECKS,1,[Disable public API sanity checking])
305
    AC_DEFINE(G_DISABLE_CHECKS,1,[Disable GLib public API sanity checking])
306
    DISABLE_UNUSED_WARNINGS="unused-label"
307
fi
308

309 310 311 312 313 314 315 316 317
AH_BOTTOM([
/* explicitly define these macros to get less confusing conditions */
#ifndef DBUS_DISABLE_ASSERT
#  define DBUS_ENABLE_ASSERT 1
#endif
#ifndef DBUS_DISABLE_CHECKS
#  define DBUS_ENABLE_CHECKS 1
#endif])

318
if test x$enable_compiler_coverage = xyes; then
319 320 321 322
     ## so that config.h changes when you toggle gcov support
     AC_DEFINE_UNQUOTED(DBUS_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
fi

323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347
# glibc21.m4 serial 3
dnl Copyright (C) 2000-2002, 2004 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

# Test for the GNU C Library, version 2.1 or newer.
# From Bruno Haible.

AC_CACHE_CHECK(whether we are using the GNU C Library 2.1 or newer,
  ac_cv_gnu_library_2_1,
  [AC_EGREP_CPP([Lucky GNU user],
    [
#include <features.h>
#ifdef __GNU_LIBRARY__
 #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || (__GLIBC__ > 2)
  Lucky GNU user
 #endif
#endif
    ],
    ac_cv_gnu_library_2_1=yes,
    ac_cv_gnu_library_2_1=no)
  ]
)

348
#### Integer sizes
349

350 351 352 353 354 355 356 357
AC_CHECK_SIZEOF(char)
AC_CHECK_SIZEOF(short)
AC_CHECK_SIZEOF(long)
AC_CHECK_SIZEOF(int)
AC_CHECK_SIZEOF(void *)
AC_CHECK_SIZEOF(long long)
AC_CHECK_SIZEOF(__int64)

358 359 360 361 362 363
AC_ARG_WITH([64-bit],
  [AS_HELP_STRING([--without-64-bit],
    [If you have to use this option, please report it as a bug])],
  [],
  [with_64_bit=yes])

364 365 366
### See what our 64 bit type is called
AC_MSG_CHECKING([64-bit integer type])

367 368 369
case 8 in
$ac_cv_sizeof_int)
  dbusint64=int
370 371
  dbusint64_constant='(val)'
  dbusuint64_constant='(val)'
372
  dbusint64_printf_modifier='""'
373 374 375
  ;;
$ac_cv_sizeof_long)
  dbusint64=long
376 377
  dbusint64_constant='(val##L)'
  dbusuint64_constant='(val##UL)'
378
  dbusint64_printf_modifier='"l"'
379 380 381
  ;;
$ac_cv_sizeof_long_long)
  dbusint64='long long'
382 383
  dbusint64_constant='(val##LL)'
  dbusuint64_constant='(val##ULL)'
384 385 386 387 388
  # Ideally we discover what the format is, but this is
  # only used in verbose mode, so eh...
  if test x"$ac_cv_gnu_library_2_1" = xyes; then
    dbusint64_printf_modifier='"ll"'
  fi
389 390 391
  ;;
$ac_cv_sizeof___int64)
  dbusint64=__int64
392 393
  dbusint64_constant='(val##i64)'
  dbusuint64_constant='(val##ui64)'
394 395 396 397
  # See above case
  if test x"$ac_cv_gnu_library_2_1" = xyes; then
    dbusint64_printf_modifier='"ll"'
  fi
398 399 400
  ;;
esac

401 402 403
AS_IF(
  [test "x$with_64_bit" = xno],
  [
404 405 406 407
        DBUS_INT64_TYPE="no_int64_type_detected"
        DBUS_HAVE_INT64=0
        DBUS_INT64_CONSTANT=
        DBUS_UINT64_CONSTANT=
408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426
        AC_MSG_RESULT([disabled via --without-64-bit])
  ],
  dnl else if
  [test -z "$dbusint64"],
  [AC_MSG_RESULT([not found])
  AC_MSG_ERROR([Could not find a 64-bit integer type.

Please report a bug here with details of your platform and compiler:

    http://bugs.freedesktop.org/enter_bug.cgi?product=DBus&component=core

To compile D-Bus with all 64-bit integer types removed (not recommended), use
the option "--without-64-bit".

This option is likely to be removed in future, unless you report that your
platform needs it.])
  ],
  dnl else
  [
427 428 429 430
        DBUS_INT64_TYPE="$dbusint64"
        DBUS_HAVE_INT64=1
        DBUS_INT64_CONSTANT="$dbusint64_constant"
        DBUS_UINT64_CONSTANT="$dbusuint64_constant"
431 432 433
	if test x"$dbusint64_printf_modifier" != x; then
		AC_DEFINE_UNQUOTED(DBUS_INT64_PRINTF_MODIFIER, [$dbusint64_printf_modifier], [Define to printf modifier for 64 bit integer type])
	fi
434
        AC_MSG_RESULT($DBUS_INT64_TYPE)
435
  ])
436 437 438 439 440

AC_SUBST(DBUS_INT64_TYPE)
AC_SUBST(DBUS_INT64_CONSTANT)
AC_SUBST(DBUS_UINT64_CONSTANT)
AC_SUBST(DBUS_HAVE_INT64)
441

442 443 444 445 446
### see what 32-bit int is called
AC_MSG_CHECKING([32-bit integer type])

case 4 in
$ac_cv_sizeof_short)
447
  dbusint32=short
448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488
  ;;
$ac_cv_sizeof_int)
  dbusint32=int
  ;;
$ac_cv_sizeof_long)
  dbusint32=long
  ;;
esac

if test -z "$dbusint32" ; then
        DBUS_INT32_TYPE="no_int32_type_detected"
        AC_MSG_ERROR([No 32-bit integer type found])
else
        DBUS_INT32_TYPE="$dbusint32"
        AC_MSG_RESULT($DBUS_INT32_TYPE)
fi

AC_SUBST(DBUS_INT32_TYPE)

### see what 16-bit int is called
AC_MSG_CHECKING([16-bit integer type])

case 2 in
$ac_cv_sizeof_short)
  dbusint16=short
  ;;
$ac_cv_sizeof_int)
  dbusint16=int
  ;;
esac

if test -z "$dbusint16" ; then
        DBUS_INT16_TYPE="no_int16_type_detected"
        AC_MSG_ERROR([No 16-bit integer type found])
else
        DBUS_INT16_TYPE="$dbusint16"
        AC_MSG_RESULT($DBUS_INT16_TYPE)
fi

AC_SUBST(DBUS_INT16_TYPE)

489
## byte order
490 491 492 493 494 495 496 497 498 499 500 501 502 503 504
case $host_os in
	darwin*)
		# check at compile-time, so that it is possible to build universal
		# (with multiple architectures at once on the compile line)
		AH_VERBATIM([WORDS_BIGENDIAN_DARWIN], [
			/* Use the compiler-provided endianness defines to allow universal compiling. */
			#if defined(__BIG_ENDIAN__)
			#define WORDS_BIGENDIAN 1
			#endif
		])
		;;
	*)
		AC_C_BIGENDIAN
		;;
esac
505 506 507 508 509 510 511

dnl **********************************
dnl *** va_copy checks (from GLib) ***
dnl **********************************
dnl we currently check for all three va_copy possibilities, so we get
dnl all results in config.log for bug reports.
AC_CACHE_CHECK([for an implementation of va_copy()],dbus_cv_va_copy,[
512
	AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
513 514
#include <stdlib.h>
	static void f (int i, ...) {
515 516 517 518 519 520 521 522 523 524
	va_list args1, args2;
	va_start (args1, i);
	va_copy (args2, args1);
	if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
	  exit (1);
	va_end (args1); va_end (args2);
	}
	int main() {
	  f (0, 42);
	  return 0;
525
	}])],
526 527 528 529
	[dbus_cv_va_copy=yes],
	[dbus_cv_va_copy=no])
])
AC_CACHE_CHECK([for an implementation of __va_copy()],dbus_cv___va_copy,[
530
	AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
531 532
#include <stdlib.h>
	static void f (int i, ...) {
533 534 535 536 537 538 539 540 541 542
	va_list args1, args2;
	va_start (args1, i);
	__va_copy (args2, args1);
	if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
	  exit (1);
	va_end (args1); va_end (args2);
	}
	int main() {
	  f (0, 42);
	  return 0;
543
	}])],
544 545 546 547 548 549 550 551 552 553 554 555 556 557 558
	[dbus_cv___va_copy=yes],
	[dbus_cv___va_copy=no])
])

if test "x$dbus_cv_va_copy" = "xyes"; then
  dbus_va_copy_func=va_copy
else if test "x$dbus_cv___va_copy" = "xyes"; then
  dbus_va_copy_func=__va_copy
fi
fi

if test -n "$dbus_va_copy_func"; then
  AC_DEFINE_UNQUOTED(DBUS_VA_COPY,$dbus_va_copy_func,[A 'va_copy' style function])
fi

559 560 561 562 563 564
AC_LANG_PUSH(C)
AC_CACHE_CHECK([whether va_lists can be copied by value],
	dbus_cv_va_val_copy,
	[AC_RUN_IFELSE([AC_LANG_PROGRAM(
[[
	#include <stdarg.h>
565
	#include <stdlib.h>
566 567
]],
[[
568
	static void f (int i, ...) {
569 570 571 572 573 574 575 576 577 578
	va_list args1, args2;
	va_start (args1, i);
	args2 = args1;
	if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
	  exit (1);
	va_end (args1); va_end (args2);
	}
	int main() {
	  f (0, 42);
	  return 0;
579 580
	}
]])],
581 582 583 584
	[dbus_cv_va_val_copy=yes],
	[dbus_cv_va_val_copy=no],
	[dbus_cv_va_val_copy=yes])
])
585
AC_LANG_POP(C)
586 587 588 589 590 591

if test "x$dbus_cv_va_val_copy" = "xno"; then
  AC_DEFINE(DBUS_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
fi


592 593 594 595
#### Atomic integers

AC_CACHE_CHECK([whether $CC knows __sync_sub_and_fetch()],
  dbus_cv_sync_sub_and_fetch,
596 597
  [AC_LINK_IFELSE([
     AC_LANG_PROGRAM([[]], [[int a = 4; int b = __sync_sub_and_fetch(&a, 4); exit(b); ]])],
598 599 600 601 602 603 604 605
     [dbus_cv_sync_sub_and_fetch=yes],
     [dbus_cv_sync_sub_and_fetch=no])
  ])

if test "x$dbus_cv_sync_sub_and_fetch" = "xyes" ; then
   have_sync=1
else
   have_sync=0
606
fi
607 608

AC_DEFINE_UNQUOTED([DBUS_USE_SYNC], [$have_sync], [Use the gcc __sync extension])
609

610
#### Various functions
611
AC_SEARCH_LIBS(socket,[socket network])
612
AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
613

614
AC_CHECK_FUNCS(vsnprintf vasprintf nanosleep usleep setenv clearenv unsetenv socketpair getgrouplist fpathconf setrlimit poll setlocale localeconv strtoll strtoull issetugid getresuid)
615

616 617 618 619 620
AC_CHECK_HEADERS([syslog.h])
if test "x$ac_cv_header_syslog_h" = "xyes"; then
  AC_CHECK_DECLS([LOG_PERROR], [], [], [[#include <syslog.h>]])
fi

621 622 623 624 625 626 627 628 629 630 631 632 633 634 635 636 637 638 639 640 641 642 643 644 645 646 647
#### Check for broken poll; taken from Glib's configure

AC_MSG_CHECKING([for broken poll])
AC_RUN_IFELSE([AC_LANG_SOURCE([[
    #include <stdlib.h>
    #include <fcntl.h>
    #include <poll.h>
    #ifdef HAVE_SYS_POLL_H
    #include <sys/poll.h>
    #endif
    int main(void) {
      struct pollfd fds[1];
      int fd;
      fd = open("/dev/null", 1);
      fds[0].fd = fd;
      fds[0].events = POLLIN;
      fds[0].revents = 0;
      if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
            exit(1);  /* Does not work for devices -- fail */
      }
      exit(0);
    }]])],
  [broken_poll=no],
  [broken_poll=yes
   AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
  [broken_poll="no (cross compiling)"])
AC_MSG_RESULT($broken_poll)
648

John Palmieri's avatar
 
John Palmieri committed
649
AC_MSG_CHECKING(for dirfd)
650
AC_LINK_IFELSE([AC_LANG_PROGRAM([[
651 652
#include <sys/types.h>
#include <dirent.h>
653
]], [[
John Palmieri's avatar
 
John Palmieri committed
654 655 656 657
DIR *dirp;
dirp = opendir(".");
dirfd(dirp);
closedir(dirp);
658 659 660
]])],
[dbus_have_dirfd=yes],
[dbus_have_dirfd=no])
John Palmieri's avatar
 
John Palmieri committed
661 662
AC_MSG_RESULT($dbus_have_dirfd)
if test "$dbus_have_dirfd" = yes; then
663
	AC_DEFINE(HAVE_DIRFD,1,[Have dirfd function])
664
else
665
	AC_MSG_CHECKING(for DIR *dirp->dd_fd)
666
	AC_LINK_IFELSE([AC_LANG_PROGRAM([[
667 668
#include <sys/types.h>
#include <dirent.h>
669
	]], [[
670 671 672 673 674
DIR *dirp;
int fd;
dirp = opendir(".");
fd = dirp->dd_fd;
closedir(dirp);
675 676 677
        ]])],
        [dbus_have_ddfd=yes],
        [dbus_have_ddfd=no])
678 679 680 681
	AC_MSG_RESULT($dbus_have_ddfd)
	if test "$dbus_have_ddfd" = yes; then
		AC_DEFINE(HAVE_DDFD,1,[Have the ddfd member of DIR])
	fi
682
fi
683

684 685
AC_CHECK_HEADERS(sys/resource.h)

Tor Lillqvist's avatar
Tor Lillqvist committed
686 687
AC_CHECK_HEADERS(dirent.h)

688 689
AC_CHECK_HEADERS(execinfo.h, [AC_CHECK_FUNCS(backtrace)])

690 691
AC_CHECK_HEADERS(errno.h)

692 693 694 695
AC_CHECK_HEADERS(signal.h)

AC_CHECK_HEADERS(locale.h)

696 697
AC_CHECK_HEADERS(byteswap.h)

698 699
AC_CHECK_HEADERS(unistd.h)

700 701
AC_CHECK_HEADERS(ws2tcpip.h)

702 703
AC_CHECK_HEADERS(alloca.h)

704 705 706 707 708 709
# Add -D_POSIX_PTHREAD_SEMANTICS if on Solaris
#
case $host_os in
    solaris*)
       CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS" ;;
esac
710

711 712 713 714 715
# checking for a posix version of getpwnam_r
# if we are cross compiling and can not run the test
# assume getpwnam_r is the posix version
# it is up to the person cross compiling to change
# this behavior if desired
716
AC_LANG_PUSH(C)
717 718
AC_CACHE_CHECK([for posix getpwnam_r],
		ac_cv_func_posix_getpwnam_r,
719 720
		[AC_RUN_IFELSE([AC_LANG_PROGRAM(
[[
721 722
#include <errno.h>
#include <pwd.h>
723 724
]],
[[
725 726 727 728
    char buffer[10000];
    struct passwd pwd, *pwptr = &pwd;
    int error;
    errno = 0;
729
    error = getpwnam_r ("", &pwd, buffer,
730
                        sizeof (buffer), &pwptr);
731 732
   return (error < 0 && errno == ENOSYS)
	   || error == ENOSYS;
733
]])],
734
	[ac_cv_func_posix_getpwnam_r=yes],
735
	[ac_cv_func_posix_getpwnam_r=no],
736 737 738 739
        [ac_cv_func_posix_getpwnam_r=yes]
)])
AC_LANG_POP(C)

740
if test "$ac_cv_func_posix_getpwnam_r" = yes; then
741 742
        AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
                [Have POSIX function getpwnam_r])
743
else
744 745
        AC_CACHE_CHECK([for nonposix getpwnam_r],
                ac_cv_func_nonposix_getpwnam_r,
746
                [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pwd.h>]], [[char buffer[10000];
747 748
                        struct passwd pwd;
                        getpwnam_r ("", &pwd, buffer,
749
                                        sizeof (buffer));]])],
750 751 752 753 754 755
                        [ac_cv_func_nonposix_getpwnam_r=yes],
                        [ac_cv_func_nonposix_getpwnam_r=no])])
                if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
                AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
                        [Have non-POSIX function getpwnam_r])
        fi
756
fi
757

758 759
dnl check for socklen_t
AC_MSG_CHECKING(whether socklen_t is defined)
760
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
761 762 763
#include <sys/types.h>
#include <sys/socket.h>
#include <netdb.h>
764
]], [[
765 766
socklen_t foo;
foo = 1;
767 768 769
]])],
[dbus_have_socklen_t=yes],
[dbus_have_socklen_t=no])
770 771 772 773 774 775
AC_MSG_RESULT($dbus_have_socklen_t)

if test "x$dbus_have_socklen_t" = "xyes"; then
    AC_DEFINE(HAVE_SOCKLEN_T,1,[Have socklen_t type])
fi

776
dnl check for writev header and writev function so we're
777 778 779
dnl good to go if HAVE_WRITEV gets defined.
AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])

780 781 782
dnl needed on darwin for NAME_MAX
AC_CHECK_HEADERS(sys/syslimits.h)

783
dnl Make it easy to check if we have MSG_NOSIGNAL without actually having to include sys/socket.h
784 785
AC_CHECK_DECLS([MSG_NOSIGNAL], [], [], [[ #include <sys/types.h>
#include <sys/socket.h> ]])
786

787 788
dnl check for flavours of varargs macros (test from GLib)
AC_MSG_CHECKING(for ISO C99 varargs macros in C)
789
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
790 791 792
int a(int p1, int p2, int p3);
#define call_a(...) a(1,__VA_ARGS__)
call_a(2,3);
793 794 795
]])],
[dbus_have_iso_c_varargs=yes],
[dbus_have_iso_c_varargs=no])
796 797 798
AC_MSG_RESULT($dbus_have_iso_c_varargs)

AC_MSG_CHECKING(for GNUC varargs macros)
799
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
800 801 802
int a(int p1, int p2, int p3);
#define call_a(params...) a(1,params)
call_a(2,3);
803 804 805
]])],
[dbus_have_gnuc_varargs=yes],
[dbus_have_gnuc_varargs=no])
806 807 808 809 810 811 812 813 814 815
AC_MSG_RESULT($dbus_have_gnuc_varargs)

dnl Output varargs tests
if test x$dbus_have_iso_c_varargs = xyes; then
    AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
fi
if test x$dbus_have_gnuc_varargs = xyes; then
    AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
fi

816 817
dnl Check for various credentials.
AC_MSG_CHECKING(for struct cmsgcred)
Simon McVittie's avatar
Simon McVittie committed
818
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
819 820
#include <sys/types.h>
#include <sys/socket.h>
Simon McVittie's avatar
Simon McVittie committed
821
]], [[
822 823 824
struct cmsgcred cred;

cred.cmcred_pid = 0;
Simon McVittie's avatar
Simon McVittie committed
825 826 827
]])],
[dbus_have_struct_cmsgcred=yes],
[dbus_have_struct_cmsgcred=no])
828 829 830 831 832
AC_MSG_RESULT($dbus_have_struct_cmsgcred)

if test x$dbus_have_struct_cmsgcred = xyes; then
    AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
fi
833

834
AC_CHECK_FUNCS(getpeerucred getpeereid)
835

836
AC_CHECK_FUNCS(pipe2 accept4)
837

838 839
#### Abstract sockets

840
if test x$enable_abstract_sockets = xauto; then
841
AC_LANG_PUSH(C)
842
warn_on_xcompile=no
843 844 845
AC_CACHE_CHECK([abstract socket namespace],
		ac_cv_have_abstract_sockets,
		[AC_RUN_IFELSE([AC_LANG_PROGRAM(
846 847 848 849 850 851 852 853 854 855
[[
#include <sys/types.h>
#include <stdlib.h>
#include <string.h>
#include <stdio.h>
#include <sys/socket.h>
#include <sys/un.h>
#include <errno.h>
]],
[[
856
  size_t slen;
857 858
  int listen_fd;
  struct sockaddr_un addr;
859

860
  listen_fd = socket (PF_UNIX, SOCK_STREAM, 0);
861

862 863 864 865 866 867 868 869 870
  if (listen_fd < 0)
    {
      fprintf (stderr, "socket() failed: %s\n", strerror (errno));
      exit (1);
    }

  memset (&addr, '\0', sizeof (addr));
  addr.sun_family = AF_UNIX;
  strcpy (addr.sun_path, "X/tmp/dbus-fake-socket-path-used-in-configure-test");
871 872 873 874
  /* SUN_LEN uses strlen() so need to calculate it before adding \0 at the
   * beginning.
   */
  slen = SUN_LEN(&addr);
875
  addr.sun_path[0] = '\0'; /* this is what makes it abstract */
876

877
  if (bind (listen_fd, (struct sockaddr*) &addr, slen) < 0)
878
    {
879
       fprintf (stderr, "Abstract socket namespace bind() failed: %s\n",
880 881 882
                strerror (errno));
       exit (1);
    }
883
  else
884 885
    exit (0);
]])],
886
              [ac_cv_have_abstract_sockets=yes],
887 888 889 890 891
              [ac_cv_have_abstract_sockets=no],
              [
                ac_cv_have_abstract_sockets=no
                warn_on_xcompile=yes
              ]
892
)])
893 894 895
if test x$warn_on_xcompile = xyes ; then
  AC_MSG_WARN([Cannot check for abstract sockets when cross-compiling, please use --enable-abstract-sockets])
fi
896
AC_LANG_POP(C)
897
fi
898 899

if test x$enable_abstract_sockets = xyes; then
900
    if test x$ac_cv_have_abstract_sockets = xno; then
901 902 903 904 905
	AC_MSG_ERROR([Abstract sockets explicitly required, and support not detected.])
    fi
fi

if test x$enable_abstract_sockets = xno; then
906
   ac_cv_have_abstract_sockets=no;
907 908
fi

909
if test x$ac_cv_have_abstract_sockets = xyes ; then
910
   DBUS_PATH_OR_ABSTRACT=abstract
911
   AC_DEFINE(HAVE_ABSTRACT_SOCKETS,1,[Have abstract socket namespace])
912 913 914 915
else
   DBUS_PATH_OR_ABSTRACT=path
fi

916 917
# this is used in addresses to prefer abstract, e.g.
# unix:path=/foo or unix:abstract=/foo
918 919
AC_SUBST(DBUS_PATH_OR_ABSTRACT)

920 921
PKG_PROG_PKG_CONFIG

922 923
#### Sort out XML library

924
AC_CHECK_LIB(expat, XML_ParserCreate_MM,
925 926 927
             [ AC_CHECK_HEADERS(expat.h, [],
                                [AC_MSG_ERROR([Could not find expat.h, check config.log for failed attempts])]) ],
             [ AC_MSG_ERROR([Explicitly requested expat but expat not found]) ])
928

929 930
XML_LIBS=-lexpat
XML_CFLAGS=
931 932
AC_SUBST([XML_CFLAGS])
AC_SUBST([XML_LIBS])
933

934
# Thread lib detection
935
AC_ARG_VAR([THREAD_LIBS])
936 937
save_libs="$LIBS"
LIBS="$LIBS $THREAD_LIBS"
938 939 940 941 942 943 944 945 946 947 948 949 950 951 952 953 954 955 956 957 958 959 960 961 962 963 964 965 966 967 968 969 970 971 972 973 974 975 976 977 978 979 980 981

is_missing_pthread_function="is required when compiling D-Bus on Unix platforms, but is not in your libc or libpthread. Please open a bug on https://bugs.freedesktop.org/enter_bug.cgi?product=dbus with details of your platform."

# Don't do these automatic checks if the user set THREAD_LIBS on the
# configure command-line. If they did, we assume they're right.
#
# We also don't do these checks on Windows, because you don't need magical
# linker flags to have threading support there.
AS_IF([test "x$dbus_unix" = xyes && test "x$THREAD_LIBS" = x],
  [
    # Mandatory pthread functions. In principle, some of these could be made
    # optional if there are platforms that don't have them.
    #
    # Currently, we only look in -lpthread.
    # In principle we might need to look in -lpthreads, -lthreads, ...
    # as well - please file a bug if your platform needs this.
    AC_SEARCH_LIBS([pthread_cond_timedwait],
        [pthread],
        [THREAD_LIBS="$LIBS"],
        [AC_MSG_ERROR([pthread_cond_timedwait $is_missing_pthread_function])],
        [])
    AC_SEARCH_LIBS([pthread_mutexattr_init],
        [pthread],
        [THREAD_LIBS="$LIBS"],
        [AC_MSG_ERROR([pthread_mutexattr_init $is_missing_pthread_function])],
        [])
    AC_SEARCH_LIBS([pthread_mutexattr_settype],
        [pthread],
        [THREAD_LIBS="$LIBS"],
        [AC_MSG_ERROR([pthread_mutexattr_settype $is_missing_pthread_function])],
        [])

    # Optional, for monotonic clocks. Because it's optional, this check
    # is non-fatal if we don't find it.
    AC_SEARCH_LIBS([pthread_condattr_setclock],
        [pthread],
        [THREAD_LIBS="$LIBS"])

    AS_IF([test "x$ac_cv_search_pthread_condattr_setclock" != xno],
      [
        AC_SEARCH_LIBS([clock_getres], [rt], [THREAD_LIBS="$LIBS"])
        AC_MSG_CHECKING([for CLOCK_MONOTONIC])
        AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
[[#include <time.h>
982
#include <pthread.h>
983
]], [[
984 985 986 987 988
struct timespec monotonic_timer;
pthread_condattr_t attr;
pthread_condattr_init (&attr);
pthread_condattr_setclock (&attr, CLOCK_MONOTONIC);
clock_getres (CLOCK_MONOTONIC,&monotonic_timer);
989
]])],
990 991 992 993 994 995 996 997 998 999 1000
            [have_clock_monotonic=true],
            [have_clock_monotonic=false])
        AS_IF([test x$have_clock_monotonic = xtrue],
	  [
            AC_MSG_RESULT([found])
            AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1, [Define if we have CLOCK_MONOTONIC])
	  ],
          [AC_MSG_RESULT([not found])])
      ]) dnl have pthread_condattr_setclock
  ]) dnl on Unix

1001
LIBS="$save_libs"
1002

1003 1004
AC_SUBST([THREAD_LIBS])

1005 1006 1007 1008 1009
# SELinux detection
if test x$enable_selinux = xno ; then
    have_selinux=no;
else
    # See if we have SELinux library
1010
    AC_CHECK_LIB(selinux, is_selinux_enabled,
1011 1012
                 have_selinux=yes, have_selinux=no)

John Palmieri's avatar
John Palmieri committed
1013
    # see if we have the SELinux header with the new D-Bus stuff in it
1014
    if test x$have_selinux = xyes ; then
1015
        AC_MSG_CHECKING([for DBUS Flask permissions in selinux/av_permissions.h])
1016 1017 1018 1019 1020 1021 1022
        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <selinux/av_permissions.h>]],
                          [[#ifdef DBUS__ACQUIRE_SVC return 0;
			    #else
			    #error DBUS__ACQUIRE_SVC not defined
			    #endif]])],
                          [have_selinux=yes],
                          [have_selinux=no])
1023
	AC_MSG_RESULT($have_selinux)
1024 1025 1026 1027 1028 1029
    fi

    if test x$enable_selinux = xauto ; then
        if test x$have_selinux = xno ; then
                AC_MSG_WARN([Sufficiently new SELinux library not found])
        fi
1030
    else
1031 1032 1033 1034 1035 1036 1037 1038 1039
        if test x$have_selinux = xno ; then
                AC_MSG_ERROR([SElinux explicitly required, and SELinux library not found])
        fi
    fi
fi

AM_CONDITIONAL(HAVE_SELINUX, test x$have_selinux = xyes)

if test x$have_selinux = xyes ; then
1040 1041 1042 1043 1044 1045
    # the selinux code creates threads
    # which requires libpthread even on linux
    AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,
                                                [SELINUX_THREAD_LIBS="-lpthread"])])

    SELINUX_LIBS="-lselinux $SELINUX_THREAD_LIBS"
1046 1047 1048 1049 1050
    AC_DEFINE(HAVE_SELINUX,1,[SELinux support])
else
    SELINUX_LIBS=
fi

1051 1052 1053 1054 1055 1056 1057 1058 1059 1060
# inotify checks
if test x$enable_inotify = xno ; then
    have_inotify=no;
else
    AC_CHECK_HEADERS(sys/inotify.h, have_inotify=yes, have_inotify=no)
fi

dnl check if inotify backend is enabled
if test x$have_inotify = xyes; then
   AC_DEFINE(DBUS_BUS_ENABLE_INOTIFY,1,[Use inotify])
1061
   AC_CHECK_FUNCS(inotify_init1)
1062 1063 1064 1065
fi

AM_CONDITIONAL(DBUS_BUS_ENABLE_INOTIFY, test x$have_inotify = xyes)

1066 1067 1068
# For simplicity, we require the userland API for epoll_create1 at
# compile-time (glibc 2.9), but we'll run on kernels that turn out
# not to have it at runtime.
1069 1070 1071 1072 1073 1074 1075 1076 1077 1078 1079 1080 1081 1082 1083 1084 1085 1086 1087 1088 1089 1090
AC_ARG_ENABLE([epoll],
              [AS_HELP_STRING([--enable-epoll],[use epoll(4) on Linux])],
              [enable_epoll=$enableval], [enable_epoll=auto])
if test x$enable_epoll = xno; then
    have_linux_epoll=no
else
    AC_MSG_CHECKING([for Linux epoll(4)])
    AC_LINK_IFELSE([AC_LANG_PROGRAM(
        [
        #ifndef __linux__
        #error This is not Linux
        #endif
        #include <sys/epoll.h>
        ],
        [epoll_create1 (EPOLL_CLOEXEC);])],
        [have_linux_epoll=yes],
        [have_linux_epoll=no])
    AC_MSG_RESULT([$have_linux_epoll])
fi
if test x$enable_epoll,$have_linux_epoll = xyes,no; then
    AC_MSG_ERROR([epoll support explicitly enabled but not available])
fi
1091 1092 1093
if test x$have_linux_epoll = xyes; then
  AC_DEFINE([DBUS_HAVE_LINUX_EPOLL], 1, [Define to use epoll(4) on Linux])
fi
1094 1095
AM_CONDITIONAL([HAVE_LINUX_EPOLL], [test x$have_linux_epoll = xyes])

John Palmieri's avatar
John Palmieri committed
1096 1097
# kqueue checks
if test x$enable_kqueue = xno ; then
1098
    have_kqueue=no
John Palmieri's avatar
John Palmieri committed
1099
else
1100 1101 1102 1103 1104 1105 1106
    have_kqueue=yes
    AC_CHECK_HEADER(sys/event.h, , have_kqueue=no)
    AC_CHECK_FUNC(kqueue, , have_kqueue=no)

    if test x$enable_kqueue = xyes -a x$have_kqueue = xno; then
        AC_MSG_ERROR(kqueue support explicitly enabled but not available)
    fi
John Palmieri's avatar
John Palmieri committed
1107 1108 1109 1110
fi

dnl check if kqueue backend is enabled
if test x$have_kqueue = xyes; then
1111
   AC_DEFINE(DBUS_BUS_ENABLE_KQUEUE,1,[Use kqueue])
John Palmieri's avatar
John Palmieri committed
1112 1113
fi

1114
AM_CONDITIONAL(DBUS_BUS_ENABLE_KQUEUE, test x$have_kqueue = xyes)
John Palmieri's avatar
John Palmieri committed
1115

Benjamin Reed's avatar
Benjamin Reed committed
1116 1117 1118 1119 1120 1121 1122 1123 1124 1125 1126 1127 1128 1129 1130 1131 1132 1133 1134 1135 1136 1137 1138 1139 1140 1141 1142 1143 1144 1145 1146 1147
# launchd checks
if test x$enable_launchd = xno ; then
    have_launchd=no
else
    have_launchd=yes
    AC_CHECK_HEADER([launch.h], , have_launchd=no)
    AC_PATH_PROG([LAUNCHCTL], [launchctl])
    if test "x$LAUNCHCTL" = "x"; then
        have_launchd=no
    fi

    if test x$enable_launchd = xyes && test x$have_launchd = xno ; then
        AC_MSG_ERROR([launchd support explicitly enabled but not available])
    fi
fi

dnl check if launchd is enabled
if test x$have_launchd = xyes; then
    AC_DEFINE(DBUS_ENABLE_LAUNCHD,1,[Use launchd autolaunch])
fi

AM_CONDITIONAL(DBUS_ENABLE_LAUNCHD, test x$have_launchd = xyes)

#### Directory to place launchd agent file
if test "x$with_launchd_agent_dir" = "x"; then
   LAUNCHD_AGENT_DIR="/Library/LaunchAgents"
else
   LAUNCHD_AGENT_DIR="$with_launchd_agent_dir"
fi

AC_SUBST(LAUNCHD_AGENT_DIR)

John Palmieri's avatar
John Palmieri committed
1148 1149 1150 1151
dnl console owner file
if test x$enable_console_owner_file = xno ; then
    have_console_owner_file=no;
else
1152
    case $host_os in
John Palmieri's avatar
John Palmieri committed
1153 1154 1155 1156 1157 1158 1159 1160 1161 1162 1163
    solaris*)
        have_console_owner_file=yes;
        AC_DEFINE(HAVE_CONSOLE_OWNER_FILE,1,[Have console owner file])
        ;;
    *)
        have_console_owner_file=no;;
    esac
fi

AM_CONDITIONAL(HAVE_CONSOLE_OWNER_FILE, test x$have_console_owner_file = xyes)

1164 1165 1166 1167 1168
dnl systemd detection
if test x$enable_systemd = xno ; then
    have_systemd=no;
else
    PKG_CHECK_MODULES(SYSTEMD,
1169
        [libsystemd-login >= 32, libsystemd-daemon >= 32],
1170 1171 1172 1173 1174 1175 1176 1177 1178 1179 1180 1181
        have_systemd=yes,
        have_systemd=no)
fi

if test x$have_systemd = xyes; then
    AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
fi

if test x$enable_systemd = xyes -a x$have_systemd != xyes ; then
    AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
fi

1182 1183 1184 1185 1186
# libaudit detection
if test x$enable_libaudit = xno ; then
    have_libaudit=no;
else
    # See if we have audit daemon & capabilities library
1187
    AC_CHECK_LIB(audit, audit_log_user_avc_message,
1188 1189
                 have_libaudit=yes, have_libaudit=no)
    if test x$have_libaudit = xyes ; then
1190
        AC_CHECK_LIB(cap-ng, capng_clear,
1191 1192 1193 1194 1195 1196 1197
                 have_libaudit=yes, have_libaudit=no)
    fi
fi

AM_CONDITIONAL(HAVE_LIBAUDIT, test x$have_libaudit = xyes)

if test x$have_libaudit = xyes ; then
1198
    SELINUX_LIBS="$SELINUX_LIBS -laudit -lcap-ng"
1199 1200 1201
    AC_DEFINE(HAVE_LIBAUDIT,1,[audit daemon SELinux support])
fi

1202 1203 1204
AC_SUBST([SELINUX_LIBS])

# Check for ADT API (Solaris Basic Security Mode auditing)
1205 1206 1207 1208 1209 1210 1211 1212 1213 1214 1215 1216 1217 1218 1219
AC_MSG_CHECKING(for ADT API)
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
#include <bsm/adt.h>
adt_user_context = ADT_USER;
]], [[]])], [ check_adt_audit=yes ], [ check_adt_audit=no ])

if test ${check_adt_audit} = yes
then
   AC_DEFINE([HAVE_ADT], [], [Adt audit API])
   ADT_LIBS="-lbsm"
   LIBS="-lbsm $LIBS"
   AC_MSG_RESULT(yes)
else
   AC_MSG_RESULT(no)
fi
1220
AC_SUBST([ADT_LIBS])
1221

1222 1223 1224
# Check for SCM_RIGHTS
AC_MSG_CHECKING([for SCM_RIGHTS])
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1225
#include <sys/types.h>
1226 1227 1228 1229 1230 1231 1232
#include <sys/socket.h>
#include <sys/un.h>
static int x = SCM_RIGHTS;
]], [[]])],
[ AC_MSG_RESULT([supported])
  AC_DEFINE([HAVE_UNIX_FD_PASSING], [1], [Supports sending UNIX file descriptors]) ],
[ AC_MSG_RESULT([not supported]) ])
1233

1234 1235
NETWORK_libs=
if test x$dbus_win = xyes ; then
1236 1237 1238
  if test x$dbus_wince = xyes ; then
    NETWORK_libs="-lws2"
  else
1239
    NETWORK_libs="-lws2_32 -liphlpapi"
1240
  fi